さあ、今回は敵UFOの親玉が弾を出します。って言っても基本は今までやってきた事と一緒です。画面上に１発しか表示されないので配列変数や二重ループも必要ないので簡単ですね♪ まず『*SYOKIKA』の所にUFO弾の各種設定情報を追加します。 次に『*MAIN』メインルーチンですが、ココにまたも1つサブルーチン『gosub *UFOTAMA』を追加します。このサブルーチンでUFO弾の移動と自機弾との当たり判定を行います。前回と全く一緒ですね・・・。 次に『*UFO』ここにUFOが弾を出すタイミングを追加します。今回は全体のゲームカウンターが300回るたびに弾を発生します。その際に、弾の初期位置の設定と最初にどちらの向きに移動するかを決めています。 さあ、『*UFOTAMA』ここからが今回のメインです・・・・って言っても毎回同じなのですが・・・・(^^; まず、いつも通りUFO弾が存在しなければその後の処理を飛ばします。存在していれば、UFO弾の移動処理をして、自機との当たり判定を行います。（今回もUFOが１機しか存在しないので二重ループの必要がありません。） 簡単に説明しますと、弾のＹ座標が300未満の時はＸ座標250〜350の間で左右に移動します。弾のＹ座標が300を超えるとＸ座標200〜400の間で左右に移動します。要は弾が下の方に来ると横の移動幅が広がると言う事です。尚、Ｘ座標の移動量も変えています。 最後にUFO弾を新しい座標に描画をしてこのルーチンも終わりです。 今回もほとんどが前回と同じなので説明を大幅に端折りました。分かりにくい場所があれば、掲示板やメールにてご質問下さい m(_ _)m 敵や弾の出現パターンや移動パターンさえ作ってしまえば、後の処理は全て同じなので、ご自分で色々とパターンを考えてみてくださいね♪ 下記のスクリプトの一部または全部において転用は自由とさせていただきますので、色々と数字を換えてお試し下さい♪ 下記スクリプトをHSPのスクリプトエディターにコピペでお使いいただけます。 |
#define SHOTMAX 2 ;自機弾最大数
#define ENEMYMAX 12 ;敵機最大数
#define TAMAMAX 36 ;敵弾最大数
buffer 2,,,1
picload "cruiser.bmp"
screen 0,640,480,1,dispx-640/2,dispy-480/2:cls 4 : title "space cruiser"
font "ＭＳ 明朝",20
gmode 2
*SYOKIKA
mx=300 : my=400 ;自機の初期位置
lv=1 ;初期レベル
myl=1 ;自機生存の有無
uf=10 ;UFO生存の有無（UFOの硬さも表現しています）
ux=160 : uy=60 ;UFOの初期位置
usx=6 ;UFOの移動初速度（Ｘ軸）
usy=8 ;UFOの移動初速度（Ｙ軸）
us=1 ;UFOの加速量
utsx=30 ;UFO弾の移動初速度（Ｘ軸）
utsy=6 ;UFO弾の移動初速度（Ｙ軸）
gcnt=1 ;ゲームカウンターの初期値
dim sf,SHOTMAX ;自弾の有無
dim sx,SHOTMAX ;自弾のＸ座標
dim sy,SHOTMAX ;自弾のＹ座標
dim ef,ENEMYMAX ;敵の硬さ
dim ex,ENEMYMAX ;敵のＸ座標
dim ey,ENEMYMAX ;敵のＹ座標
dim et,ENEMYMAX ;敵発生からのカウンター
dim esx,ENEMYMAX ;敵のＸ軸移動量
dim esy,ENEMYMAX ;敵のＹ軸移動量
dim tf,TAMAMAX ;敵弾の有無
dim tx,TAMAMAX ;敵弾のＸ座標
dim ty,TAMAMAX ;敵弾のＹ座標
dim tk,TAMAMAX ;敵弾の種類（垂直OR斜頚）
dim td,TAMAMAX ;敵弾の弾道（方向）
dim ts,TAMAMAX ;敵弾の移動速度
*MAIN ;メインループ
palcolor 0 : boxf 0,0,640,480
if myl>0 : gosub *JIKI
gosub *TAMA
if enemy=0 : gosub *TEKI
gosub *TEKIMOVE
gosub *TAMAMOVE
gosub *UFO
gosub *UFOTAMA
redraw 1 : redraw 2 : await 30
gcnt+
goto *MAIN
*JIKI ;自機の移動・ショットキーチェック
stick bt,5 : k- : if k<1 : if bt&16 : ff=1 : k=3
mxv=(bt&4!0):mxv-=(bt&1!0)
mx+=mxv*8
if mx<0 : mx=0
if mx>580 : mx=580
pos mx,my : gcopy 2,0,32,64,64
return
*TAMA ;自機弾の移動・表示
repeat SHOTMAX
if ff>0 : if sf.cnt=0 : ff- : sf.cnt=1 : sx.cnt=mx+16 : sy.cnt=my-20
if sf.cnt=0 : continue
sy.cnt-=12 : if sy.cnt<-32 : sf.cnt=0
pos sx.cnt,sy.cnt : gcopy 2,96,0,32,32
loop
return
*TEKI ;敵の出現
repeat ENEMYMAX
if cnt<12 {
if cnt<10 {
if cnt<8 {
if cnt<6 {
if cnt<4 {
if cnt<2 { ef.cnt=1 : ex.cnt=cnt*100+100 : ey.cnt=80
pos ex.cnt,ey.cnt : gcopy 2,lv*32,0,32,32
}else{ ef.cnt=1 : ex.cnt=cnt-2*100+100 : ey.cnt=130
pos ex.cnt,ey.cnt : gcopy 2,lv*32,0,32,32 }
}else{ ef.cnt=1 : ex.cnt=cnt-4*100+100 : ey.cnt=180
pos ex.cnt,ey.cnt : gcopy 2,lv*32,0,32,32 }
}else{ ef.cnt=1 : ex.cnt=cnt-5*100+300 : ey.cnt=80
pos ex.cnt,ey.cnt : gcopy 2,lv*32,0,32,32 }
}else{ ef.cnt=1 : ex.cnt=cnt-7*100+300 : ey.cnt=130
pos ex.cnt,ey.cnt : gcopy 2,lv*32,0,32,32 }
}else{ ef.cnt=1 : ex.cnt=cnt-9*100+300 : ey.cnt=180
pos ex.cnt,ey.cnt : gcopy 2,lv*32,0,32,32 }
}
esx.cnt=5 : esy.cnt=5 : et.cnt=0
enemy=1
loop
return
*TEKIMOVE ;敵の移動処理・当たり判定
repeat ENEMYMAX
if ef.cnt<1 : continue
et.cnt++
if cnt<6 {
ex.cnt-=esx.cnt : if et.cnt>20 : et.cnt=-20 : esx.cnt=-esx.cnt
ey.cnt+=esy.cnt : if (ey.cnt>200)|(ey.cnt<50) : esy.cnt=-esy.cnt
}else{
ex.cnt+=esx.cnt : if et.cnt>20 : et.cnt=-20 : esx.cnt=-esx.cnt
ey.cnt+=esy.cnt : if (ey.cnt>200)|(ey.cnt<50) : esy.cnt=-esy.cnt
}
ent=cnt
repeat SHOTMAX
if sf.cnt=0 : continue
dx=(ex.ent+16)-(sx.cnt+16) : if dx<0 : dx=-dx
dy=(ey.ent+16)-(sy.cnt+16) : if dy<0 : dy=-dy
if dx<10 : if dy<10 {
ef.ent- : sf.cnt- : pos ex.ent,ey.ent : palcolor 255 : mes "●"
}
loop
rnd tam,200 : if tam=0 {
repeat TAMAMAX
if tf.cnt>0 : continue
tf.cnt+ : tx.cnt=ex.ent : ty.cnt=ey.ent
rnd ts.cnt,5 : ts.cnt+=5
rnd tk.cnt,3 : if tk.cnt=0 : tk.cnt=1
dx=ex.ent-mx : if dx<0 : td.cnt=-3 : else : td.cnt=3
break
loop
}
pos ex.cnt,ey.cnt : gcopy 2,lv*32,0,32,32
loop
return
*TAMAMOVE ;敵弾の移動＆当たり判定
repeat TAMAMAX
if tf.cnt<1 : continue
if tk.cnt=1 : ty.cnt+=ts.cnt : else : ty.cnt+=ts.cnt : tx.cnt-=td.cnt
if ty.cnt>480 : tf.cnt-
ent=cnt
repeat SHOTMAX
if sf.cnt=0 : continue
dx=(tx.ent+16)-(sx.cnt+16) : if dx<0 : dx=-dx
dy=(ty.ent+16)-(sy.cnt+16) : if dy<0 : dy=-dy
if dx<5 : if dy<10 {
tf.ent- : sf.cnt- : pos sx.cnt,sy.cnt : palcolor 255 : mes "●"
}
loop
if myl<1 : continue
dx=(tx.cnt+16)-(mx+32) : if dx<0 : dx=-dx
dy=(ty.cnt+16)-(my+32) : if dy<0 : dy=-dy
if dx<20 : if dy<30 {
tf.cnt- : myl- : pos mx,my : palcolor 255 : mes "○◎○"
}
pos tx.cnt,ty.cnt : gcopy 2,128,0,32,32
loop
return
*UFO ;UFO移動＆当たり判定
if uf<1 : return
ux+=usx : uy-=usy
if (usy<-10)|(usy>10) : us=-us
usy-=us
if (ux<160)|(ux>400) : usx=-usx
repeat SHOTMAX
if sf.cnt=0 : continue
dx=(ux+48)-(sx.cnt+16) : if dx<0 : dx=-dx
dy=(uy+16)-(sy.cnt+16) : if dy<0 : dy=-dy
if dx<20 : if dy<10 {
uf- : sf.cnt- : pos sx.cnt,sy.cnt : palcolor 255 : mes "●"
}
loop
pos ux,uy : gcopy 2,64,(ufn+1)*32,96,32
if gcnt\20<1 : ufn=ufn+1\2
if gcnt\300<1 : if myl>0 {
utf+ : utx=ux+48 : uty=uy+16 : if ux>300 : utsx=-utsx
}
return
*UFOTAMA ;UFOの弾移動＆当たり判定
if utf<1 : return
utx+=utsx : uty+=utsy
if uty>300 { if utx<200 : utsx+=10
if utx>400 : utsx-=10
} else {
if utx<250 : utsx+=8
if utx>350 : utsx-=8
}
if uty>480 : utf- : utsx=30
dx=(utx+32)-(mx+32) : if dx<0 : dx=-dx
dy=(uty+32)-(my+32) : if dy<0 : dy=-dy
if dx<20 : if dy<30 {
utf- : myl- : utsx=30 : pos mx,my : palcolor 255 : mes "○◎○"
}
pos utx,uty : gcopy 2,0,0,32,32
return
↑こんな感じです。UFOが必殺ボムを投下します♪
これだけでも難易度が結構上がるんですよ(^^);
上手く出来たら、次に行ってみましょう♪
NEXT ->>